TheGameCreators - CodeBase - Easy to Use 3D Explosion Generator

Return to the CodeBase listing

Category: 3D Effects

Version: 1.0

Information

Uploaded: 6th Jan 2007 17:23

Modified: 9th Feb 2007 14:11

Author: Trek

Summary

Function-based code allowing easy explosion generation and animation in your games.

Full Description

In preperation for the current production I'm working on, I decided to make several functions which would allow me to make an explosion with a custom position, size, angle, animation, and animation speed with a single function call and then allow me to animate all my explosions with another single function call. I also didn't want to be bothered with deleting my explosions when they were done or making sure I didn't have problems with their object numbers interfering with my other object numbers. This code, accomplishes all those objectives in a very easy to use and efficient way. First you simply setup the generator with a function call specifying what range of object numbers you want to be allocated for the explosion objects. Then, you simply put a single function call in your main loop to update the explosions. Now, whenever you want to trigger an explosion, you simply call a TriggerExplosion() function and pass it the specifics of the explosion you want to occur. The code is also highly commented for easy use and future customization. No credit is required if you use this code but is definitely appreciated. You must download the attached image file and include it in the same directory as the code in order for the example to run but not if you would simply like to include the functions in your own program. If you're interested in some of my company's productions check out www.TrekSoftware.org Also, if you have any questions about this code snippet, you can sign up on the Trek Software forum linked to on my website and ask your questions there.

DarkBASIC Professional Source Code

` This code was downloaded from The Game Creators

` It is reproduced here with full permission

` http://www.thegamecreators.com

` Explosion Generator - version 1.0

` Programmed by D3

` www.TrekSoftware.org

` Basic setup stuff

autocam off

sync on

sync rate 30

hide mouse

position camera 0,0,0

point camera 0,0,5

color backdrop rgb(20,30,50)

set ambient light 100

` Load the image for our animation and split it up into 30 seperate images.

` You can either do this or if each frame of your animation is in a seperate

` image, simply load them all up in sequential order (i.e. the first frame is n, the next is n+1, etc.)

load image "1.png",1

split_image(1,6,5,10)

`The animation frames in image 1 get turned into images with numbers 10-39

` This sets up the variables for the generator and also allows you to specify what range of objects you want

` the generator to be allowed to use. If the generator ever needs more objects then are provided by the range

` it shows a text error on the screen saying that the bounds have been exceeded but doesn't crash your program.

InitializeGenerator(100,200)

` This is the basic call for making any explosion. The paramaters are as follows:

` X Position, Y Position, Z Position, First Image in Animation, Last Image in Animation, Angle X, Angle Y, Angle Z

` Size X, Size Y, Time Delay (in seconds) beween animation frames.

` Thus, this function call makes an explosion postioned at 0,0,5 with a horizontal size 4 and vertical size 4 which

` will animate images 10 - 39 with a .01 second time delay between each frame.

TriggerExplosion(0,0,5,10,39,0,0,0,4,4,.01)

` Whenever the spacekey is pressed, a random explosion is generated using the TriggerExplosion call.

if spacekey()=1 then TriggerExplosion(rnd(6)-3,rnd(4)-2,5,10,39,0,0,0,rnd(4)+1,rnd(4)+1,.05)

` In order to animate your explosions, all you need to do is put this function call in your main loop.

ControlExplosions()

sync

loop

` ----------------------------------------------------------------------------------------------------------

` To use the above commands, you need to include all the functions below this line up to the next line.

` ----------------------------------------------------------------------------------------------------------

` Initializes the global variables used by the generator.

` All are started with the characters "EG_" so as not to override any other variables or dimensions used in

` your program.

function InitializeGenerator(sOR, eOR)

global EG_startOfRange = sOR

global EG_endOfRange = eOR

global EG_nextId = sOR

DIM EG_animData#(eOR - sOR,11)

DIM EG_explosionStatus(eOR-sOR,3)

endfunction

` The function which creates an explosion and initializes it's data.

` It first checks to see if there are any deleted explosions. If so, it's number will be the number of the first deleted

` explosion in the range. Otherwise, it gets a number one greater than the greatest current explosion object number.

` If that number is outside the specified range, it simply displays a text error message on the screen for a little while

` alerting that the bounds have been exceeded.

` If you ever want to change the object used for an explosion or its properties, feel free to change the code in lines 92-96.

` Just be careful to always specify an object number of expID.

function TriggerExplosion(x#, y#, z#, firstImage, lastImage, angleX, angleY, angleZ, sizeX#, sizeY#, speed#)

expId = 0

counter = EG_startOfRange

while counter < EG_nextId-1

if object exist(counter)=0 then expId = counter : exit

counter = counter + 1

endwhile

if expId = 0

expId = EG_nextId

EG_nextId = EG_nextId + 1

endif

if expID > EG_endOfRange

for n=1 to 50 : center text screen width()/2,screen height()/2,"***ERROR - Explosion Bounds Exceeded***" : sync : next n

exitfunction

endif

make object plain expID, sizeX#, sizeY#

position object expID,x#,y#,z#

rotate object expID,angleX,angleY,angleZ

texture object expID,firstImage

ghost object on expID

EG_animData#(expID-EG_startOfRange,1)=x#

EG_animData#(expID-EG_startOfRange,2)=y#

EG_animData#(expID-EG_startOfRange,3)=z#

EG_animData#(expID-EG_startOfRange,4)=firstImage

EG_animData#(expID-EG_startOfRange,5)=lastImage

EG_animData#(expID-EG_startOfRange,6)=angleX

EG_animData#(expID-EG_startOfRange,7)=angleY

EG_animData#(expID-EG_startOfRange,8)=angleZ

EG_animData#(expID-EG_startOfRange,9)=sizeX#

EG_animData#(expID-EG_startOfRange,10)=sizeY#

EG_animData#(expID-EG_startOfRange,11)=speed#

endfunction

` A helper function that returns the correct texture number for a specific time for a given explosion object.

function ExplosionAnimation(AnimNumber)

if EG_explosionStatus(AnimNumber,1)=0 then EG_explosionStatus(AnimNumber,1)=EG_animData#(AnimNumber,4)

if EG_explosionStatus(AnimNumber,2)=0 then EG_explosionStatus(AnimNumber,2)=timer() : EG_explosionStatus(AnimNumber,3)=timer()+(EG_animData#(AnimNumber,11)*1000)

if timer()>=EG_explosionStatus(AnimNumber,3)

if EG_explosionStatus(AnimNumber,1)<=int(EG_animData#(AnimNumber,5))

EG_explosionStatus(AnimNumber,1)=EG_explosionStatus(AnimNumber,1)+1

else

EG_explosionStatus(AnimNumber,1)=EG_animData#(AnimNumber,4)

endif

EG_explosionStatus(AnimNumber,2)=0

endif

ReturnVal=EG_explosionStatus(AnimNumber,1)

endfunction ReturnVal

` The main animation function which runs through all the active (or possibly active) explosions and textures them or deletes them

` if they've come to the last texture in their animation.

function ControlExplosions()

for n = 0 to EG_nextId - EG_startOfRange

if object exist(n+EG_startOfRange)=1

tex = ExplosionAnimation(n)

if tex<EG_animData#(n,5)

texture object n+EG_startOfRange,tex

else

texture object n+EG_startOfRange,tex

KillExplosion(n)

endif

next n

endfunction

` A helper function for deleting explosions and resetting their data.

function KillExplosion(n)

delete object n+EG_startOfRange

for i=1 to 3

EG_explosionStatus(n,i)=0

next i

for i=1 to 11

EG_animData#(n,i)=0

next i

endfunction

` ----------------------------------------------------------------------------------------------------------

` Just an extra function written by someone else that's not necessary for the Explosion Generator to work but

` is an independent function which will split up a single image containing various animation frames into seperate

` images each containing a single frame.

function split_image(baseImage,imgX,imgY,firstImg)

baseSprite = 1

while sprite exist(baseSprite) = 1

inc baseSprite

endwhile

sprite baseSprite,0,0,baseImage

memNo = 1

while memblock exist(memNo) = 1

inc memNo

endwhile

make memblock from image memNo,baseImage

iW = (memblock dword(memNo,0))

iH = (memblock dword(memNo,4))

iD = (memblock dword(memNo,8))

imgWidth = iW / imgX

imgHeight = iH / imgY

mbSize = ((imgWidth * imgHeight) + 3) * 4

memNo2 = memNo + 1

while memblock exist(memNo2) = 1

inc memNo2

endwhile

make memblock memNo2, mbSize

write memblock dWord memNo2,0,imgWidth

write memblock dWord memNo2,4,imgHeight

write memblock dWord memNo2,8,iD

for imagesY = 1 to imgY

for imagesX = 1 to imgX

img = ((imagesY -1) * imgX) + imagesX

NewByte = 12

for rows = 1 to imgHeight

for cols = 1 to imgWidth

offSet1 = (imagesY - 1) * imgWidth * imgHeight * imgX

offset2 = (iW * (rows - 1))

offset3 = imgWidth * (imagesX - 1)

offset4 = cols - 1

imgDword = (offset1 + offset2 + offset3 + offset4 + 3) * 4

write memblock dWord memNo2,NewByte, memblock dWord(memNo,imgDWord)

inc NewByte,4

next cols

next rows

NewByte = 12

make image from memblock (img + firstImg - 1),memNo2

next imagesX

next imagesY

delete memblock memNo

delete memblock memNo2

delete sprite BaseSprite

delete image baseImage

endfunction 0

Download

Please login to download

Comments

No comments yet.

Author Name:	Trek
CodeBase Entries:	19

CodeBase - Easy to Use 3D Explosion Generator

Information

Summary

Full Description

DarkBASIC Professional Source Code

Download

Screen Shot

Author

Comments