TheGameCreators - CodeBase - Quake-Style Console

Category: Miscellaneous

Version: 0.001

Information

Uploaded: 4th Mar 2004 16:11

Modified: 1st Jan 1970 01:00

Author: adr

Summary

Sometimes, you want to be able to accurately control an element in-game. I decided to write a quake-style console for DBP and since then, I haven't looked back. This console allows you to issue commands such as "move object(4,5.3,3.2,1.2)"... If you find it useful then let me know, or drop in a credit. Please note that this will require editing before it will work. I've left in some of my code handling routines to show you what it can do and what you should edit.

Full Description

DarkBASIC Professional Source Code

` This code was downloaded from The Game Creators

` It is reproduced here with full permission

` http://www.thegamecreators.com

setupConsole:

global consoleLines = 20

global dim consoleText(consoleLines) as string

global dim consoleParams(15) as string

global consoleShowing as boolean

global consoleRequest as boolean

consoleShowing = 0

consoleRequest = 0

consoleText(consoleLines) = ""

return

function handleConsole()

` -- replace control_console() with your scancode check

if control_console() AND consoleRequest = 0:

consoleShowing = 1 - consoleShowing

consoleRequest = 1

clear entry buffer

endif

if control_console() = 0 AND consoleRequest = 1 then consoleRequest = 0

if consoleShowing = 1:

text 0,0,"======================= Welcome to Console ======================="

text 0,11*(consoleLines+1),"=================================================================="

for i = 1 to len(entry$())

char$ = mid$(entry$(),i)

j = asc(char$)

if j = 8 then consoleText(consoleLines) = left$(consoleText(consoleLines), len(consoleText(consoleLines))-1)

if j = 13 then issueCommand()

if j <> 8 AND j <> 13 then consoleText(consoleLines) = consoleText(consoleLines) + char$

clear entry buffer

next i

for i = 1 to consoleLines

text 0,11*i,consoleText(i)

next i

endif

endfunction

function issueCommand()

` -- use a select/case to map string input to a call back

cmd$ = consoleText(consoleLines)

left_bracket = strpos(cmd$, "(", 1)

right_bracket = strpos(cmd$, ")", 1)

if (left_bracket > 0 AND right_bracket > 0) then cmd$ = setParams(cmd$, left_bracket, right_bracket) else cmd$ = trim(cmd$)

select cmd$

case "":

consoleText(consoleLines) = ""

endcase

case "restart":

gosub setupNodes

nudgeConsole()

consoleText(consoleLines) = ">OK - nodes restarted!"

endcase

case "add car":

i = val(consoleParams(1))

if i > 0 AND i <= MAX_CARS:

addCar(i)

nudgeConsole()

consoleText(consoleLines) = ">OK - car added!"

endif

endcase

case "set gravity":

if consoleParams(1) <> "":

grav# = val(consoleParams(1))

set vector3 VEC_GRAVITY, 0,grav#,0

nudgeConsole()

consoleText(consoleLines) = ">Gravity set to "+str$(grav#)

else

nudgeConsole()

consoleText(consoleLines) = ">'set gravity' expects a parameter"

endif

endcase

case "move object":

if consoleParams(1) <> "":

o = val(consoleParams(1))

x# = val(consoleParams(2))

y# = val(consoleParams(3))

z# = val(consoleParams(4))

position object o, object position x(o)+x#, object position y(o)+y#, object position z(o)+z#

nudgeConsole()

consoleText(consoleLines) = ">positioned ok"

endif

endcase

case "set matrix trim":

if consoleParams(1) <> "":

set matrix trim 1, val(consoleParams(1)), 0.0006

update matrix 1

nudgeConsole()

consoleText(consoleLines) = ">matrix updated ok"

endif

endcase

case default:

nudgeConsole()

consoleText(consoleLines) = ">unknown command '"+cmd$+"'"

endcase

endselect

nudgeConsole()

consoleText(consoleLines) = ""

endfunction

function setParams(cmd$, left_bracket, right_bracket)

` -- setParams works by first, separating the parameters string by breaking the string

` -- off at the first left bracket. params$ is then trimmed for the end brackets

` -- leaving just a string of comma separated parameters.

` -- We loop through param$, starting at the first character, finding the next comma.

` -- With each iteration, params$ has the first parameter chopped off, leaving

` -- us with the remaining list of parameters. If we can't find any more commas,

` -- we must be at the last parameter. hooray.

params$ = right$(cmd$, right_bracket-left_bracket) `-- chop off stuff before bracket

params$ = left$(params$, len(params$)-1) `-- chop off trailing bracket

i = strpos(params$, ",", 1)

if (i < 0) then consoleParams(1) = params$ else i = 1

paramNum = 1

while i > -1 `-- only do this while we have parameters remaining

j = strpos(params$, ",", 2) `-- find out if there's another parameter

if (j < 0):

i = -1 `-- don't run this loop again... it's all over

j = len(params$)+1

else

i = 1 `-- we'll start from the start of the string again

endif

consoleParams(paramNum) = left$(params$, j-1) `-- store the parameter

consoleParams(paramNum) = trim(consoleParams(paramNum))

params$ = right$(params$, len(params$)-j) `-- remove the processed parameter

inc paramNum

endwhile

cmd$ = left$(cmd$, left_bracket-1) `-- grab the stuff left of the bracket

cmd$ = trim(cmd$) `-- trim off possible spaces

endfunction cmd$

function nudgeConsole()

` -- knock all the console lines up by one line

for i = 1 to consoleLines-1

consoleText(i) = consoleText(i+1)

next i

endfunction

function strpos(haystack$, needle$, offset)

l_haystack = len(haystack$)

if offset > l_haystack then exitfunction -1

for i = offset to l_haystack

if mid$(haystack$, i) = needle$ then exitfunction i

next i

endfunction -1

function right_trim(s$)

while right$(s$,1) = " "

s$ = left$(s$, len(s$)-1)

endwhile

endfunction s$

function left_trim(s$)

while left$(s$, 1) = " "

s$ = right$(s$, len(s$)-1)

endwhile

endfunction s$

` -- combine the previous two functions

function trim(s$)

s$ = right_trim(s$)

s$ = left_trim(s$)

endfunction s$

Download

Please login to download

Comments

No comments yet.

Author Name:	adr
CodeBase Entries:	2

CodeBase - Quake-Style Console

Information

Summary

Full Description

DarkBASIC Professional Source Code

Download

Screen Shot

Author

Comments