TheGameCreators - CodeBase - SUPER Fast memblock matrix

Category: Mesh

Version: 1.0

Information

Uploaded: 20th Jul 2007 23:45

Modified: 23rd Jul 2007 23:16

Author: Visigoth

Summary

makes a matrix up to 100 squares by 100 squares (20,000 polygons). Can be called in real time. After you create it, you can just make a mesh and lock the vertexdata to adjust the height points to what you want. All verts are already welded.

Full Description

params are id is object number, x_width# is how wide the grid is, z_height# is how deep the grid is, x_cols is how many squares along the x_axis, z_rows is how many squares along the z axis.

DarkBASIC Professional Source Code

` This code was downloaded from The Game Creators

` It is reproduced here with full permission

` http://www.thegamecreators.com

function make_geo_grid(id as integer, x_width# as float, z_height# as float, x_cols as integer, z_rows as integer,clr as dword)

rem This code created by Visigoth, aka Mike Shihrer

rem You may use this, modify it,etc, but give credit where credit is due.

a_time# = timer()

rem the a_time#, b_time#, and t_time# vars are for testing how fast this draws, which is PRETTY FREAKING FAST!

rem limit size to 20k polys maximum

If x_cols > 100

x_cols = 100

endif

If z_rows > 100

z_rows = 100

endif

total_verts = ((x_cols + 1) * (z_rows + 1))

total_polys = (x_cols * z_rows) * 2

total_cells = (x_cols * z_rows)

real_verts = (total_polys * 3)

cell_width# = x_width# / x_cols

cell_height# = z_height# / z_rows

mem_size = (real_verts * 36) + 12

x_pos# = 0

y_pos# = 0

z_pos# = 0

mem_pos = 12

df_clr as dword

df_clr = clr

rem memblock for storing vertice list

rem I wish they had an option here to specify the number of faces, so you would only need a list of

rem duplicate verts, not every vert for every triangle

make memblock 1,mem_size

write memblock dword 1,0,338

write memblock dword 1,4,36

write memblock dword 1,8,real_verts

rem calculate list of unique verts and put into memblock

col = 0

row = 0

for i = 1 to real_verts

write memblock float 1,mem_pos,x_pos# : inc mem_pos,4                   rem x coord

write memblock float 1,mem_pos,y_pos# : inc mem_pos,4                   rem y coord

write memblock float 1,mem_pos,z_pos# : inc mem_pos,4                   rem z coord

write memblock float 1,mem_pos,0 : inc mem_pos,4                        rem x normal

write memblock float 1,mem_pos,1 : inc mem_pos,4                        rem y normal

write memblock float 1,mem_pos,0 : inc mem_pos,4                        rem z normal

write memblock dword 1,mem_pos,df_clr : inc mem_pos,4                   rem diffuse color

write memblock float 1,mem_pos,0 : inc mem_pos,4                        rem U coord

write memblock float 1,mem_pos,1 : inc mem_pos,4                        rem z coord

inc col,1

inc x_pos#,cell_width#

if col = (x_cols + 1)

col = 0

inc z_pos#,cell_height#

x_pos# = 0

endif

next i

rem It won't let me change the vertexdata if I make a mesh from a memblock, so I have to make an object, then a mesh

make mesh from memblock 1,1

make object id,1,0

delete mesh 1

make mesh from object 1,id

delete object id

rem reorder the indexdata to point at the correct vertices (weld the verts)

rem this is the algorithem for the triangle strip we are drawing

v1_1 = 0

v1_2 = (x_cols + 1)

v1_3 = 1

v2_1 = (x_cols + 1)

v2_2 = (x_cols + 2)

v2_3 = 1

i_pos = 0

lock vertexdata for mesh 1

delete mesh from vertexdata total_verts,real_verts,0,0         rem get rid of all the verts we don't need in the vertex data

col = 0

for i = 1 to total_cells

set indexdata i_pos,v1_1 : inc i_pos,1 : inc v1_1,1            rem triangle 1, vertice 1

set indexdata i_pos,v1_2 : inc i_pos,1 : inc v1_2,1            rem triangle 1, vertice 2

set indexdata i_pos,v1_3 : inc i_pos,1 : inc v1_3,1            rem triangle 1, vertice 3

set indexdata i_pos,v2_1 : inc i_pos,1 : inc v2_1,1            rem triangle 2, vertice 1

set indexdata i_pos,v2_2 : inc i_pos,1 : inc v2_2,1            rem triangle 2, vertice 2

set indexdata i_pos,v2_3 : inc i_pos,1 : inc v2_3,1            rem triangle 2, vertice 3

inc col,1

If col = x_cols

col = 0

inc v1_1,1 : inc v1_2,1 : inc v1_3,1

inc v2_1,1 : inc v2_2,1 : inc v2_3,1

endif

next i

rem set uv coordinates to stretch across object

rem loop throught the texture coordinates and determine what percent of total width, height the vertex is at

a = get vertexdata vertex count()

for i = 0 to a

set vertexdata uv i, get vertexdata position x(i) / x_width#, get vertexdata position z(i) / z_height#

next i

unlock vertexdata

make object id,1,0

rem save it here if you want to load it as an .x file

rem save mesh "test_new_grid.x",1

delete mesh 1

delete memblock 1

b_time# = timer()

tw_time# = (b_time# - a_time#) * .001   rem WOW!

endfunction

Download

Please login to download

Comments

No comments yet.

Author Name:	Visigoth
CodeBase Entries:	18

CodeBase - SUPER Fast memblock matrix

Information

Summary

Full Description

DarkBASIC Professional Source Code

Download

Screen Shot

Author

Comments