TheGameCreators - CodeBase - FPS code with mini view that uses a dbo level or map

Category: World

Version: 1.0

Information

Uploaded: 11th Jul 2009 14:49

Modified: 11th Jul 2009 15:07

Author: Softwizz

Summary

This is code I am working on to give FPS (first person shooter) control for maps (or levels) in the dbo format. I myself am using '3D World Studio'

Full Description

This is code I am working on to give FPS (first person shooter) control for maps (or levels) in the dbo format. I myself am using '3D World Studio' You must forgive the crap comments in my code as it is a mixture of stuff gleaned from the forums and changed to work. This code uses 'sparky's collision dll' and parts of the code are adapted from the 'sliding demo' that comes with the dll You will need to replace media/skyspheregrey.bmp with your own sky image you will need to replace media/level2.dbo with your own level the radius# variable is the player size you will need to change this line: if keystate(46)=1 then radius# = 15.0 else radius#= 24.5 : ` hold c to crouch as well if you change the radius value When I build my maps in 3D World Studio I always make the spawn point at o,o,o and build the map around this point. Remember this is a work in progress and is put up here more for a backup of the code than anything else, but feel free to use it if it is helpfull

DarkBASIC Professional Source Code

` This code was downloaded from The Game Creators

` It is reproduced here with full permission

` http://www.thegamecreators.com

Rem Project: level 2

Rem Created: 11/07/2009 20:41:09

Rem ***** Main Source File *****

rem set display mode 800,600,32

sync on : sync rate 0 : hide mouse

autocam off

rem backdrop off

makeLevel()

makePlayer()

global rtimer as integer

global stimer as integer

global vtimer as integer

rem player movement vector

global vx# as double float

global vy# as double float

global vz# as double float

global x# as double float

global oldy# as double float

global z# as double float

global runon# as double float : runon# = 2.5 : ` used for run instead of walk

global radius# as double float : radius# = 24.5 : ` size of player collision sphere

global fpsviewy# as double float

global gravity# as double float : gravity# = -0.1

global slope# as double float : slope# = 0.5

global ground as integer : ground = 1

global jumptimer as integer : jumptimer = 0

movePlayer()

positionCameraToObject(2,0)

makeMinimap(x#,oldy#,z#)

text 0,0,"FPS: "+str$(screen fps())

sync

loop

function makeLevel()

make object sphere 10,-50000 : ` create skysphere a size in minus will make it inverted

load image "media/skyspheregrey.bmp",5 : ` sky texture

texture object 10,5 : ` apply sky texture to skysphere

load object "media/level2.dbo",1 : `load level

sc_setupComplexObject 1,1,2

position object 1,0,0,0 : `position level

position object 10,0,0,0 : ` position skysphere remove if sky moves with player

make camera 2 : ` minicamera

endfunction

function makePlayer()

make object sphere 2,radius#

position object 2,10,50,75

sc_setupObject 2,0,1

hide object 2

rem player has no group

endfunction

function movePlayer()

rem rotate player with mouse

yrotate object 2,object angle y(2)+mousemovex()/3.0

xrotate object 2,object angle x(2)+mousemovey()/3.0

oldx# = object position x(2)

oldy# = object position y(2)

oldz# = object position z(2)

rem apply gravity, and user changes to movement

angy# = object angle y(2)

vx# = 0

vz# = 0

rem if player is jumping or falling then apply 'normal' gravity

rem if not attempt to keep the player stuck to the floor

if vy#=0 and jumptimer=0 then vy# = vy# + 10*gravity# else vy# = vy# + gravity#

if keystate(42)=1 then runon# = 5 else runon#= 2.5 : ` hold leftshift to run

if keystate(46)=1 then radius# = 15.0 else radius#= 24.5 : ` hold c to crouch

if keystate(32)=1 then vx# = vx# + cos(angy#)*runon# : vz# = vz# - sin(angy#)*runon#

if keystate(30)=1 then vx# = vx# - cos(angy#)*runon# : vz# = vz# + sin(angy#)*runon#

if keystate(31)=1 then vx# = vx# - sin(angy#)*runon# : vz# = vz# - cos(angy#)*runon#

if keystate(17)=1 then vx# = vx# + sin(angy#)*runon# : vz# = vz# + cos(angy#)*runon#

rem only jump if on ground, and a certain time after last jump

if ground=1

if spacekey()=1 and jumptimer=0 then vy# = vy# + 4.0 : jumptimer = 20

endif

rem this would be the player's final position without collision

x# = oldx#+vx#

y# = oldy#+vy#

z# = oldz#+vz#

rem first handle gravity - seperated from horizontal movement

rem to achieve a more realistic effect

rem Method: simple - cast a sphere vertically down, if it hits the level then

rem                  position the object there (sticky collision) then move

rem                  on to horizontal movement

rem   more complex - if we were to only use the simple method the player would be

rem                  allowed to climb almost vertical slopes. Alternative is to

rem                  get the normalY direction to work out how flat the gorund

rem                  below the player is, 0-slope# is flatter, slope#-1 is steeper.

rem                  if it's flat, use sticky collision, if it's steep slide the

rem                  player down the slope. Changing slope# determines how steep the

rem                  player can climb. NOTE: this also effects stairs.

collide = sc_SphereCastGroup(1,oldx#,oldy#,oldz#,oldx#,oldy#+vy#,oldz#,radius#,0)

if collide>0

rem how flat is this ground

ny# = sc_getCollisionNormalY()

if abs(ny#)>slope#

rem FLAT, stick

oldy# = sc_getStaticCollisionY()

else

rem STEEP, slide

x# = x# - oldx# : z# = z# - oldz#

oldx# = sc_getCollisionSlideX()

oldy# = sc_getCollisionSlideY()

oldz# = sc_getCollisionSlideZ()

x# = x# + oldx# : z# = z# + oldz#

endif

rem ny#<0 means the player has hit a ceiling rather than a floor

if ny#>slope#

rem only on ground if standing on flat ground

ground = 1

vy# = 0

else

ground = 0

rem if player has hit a flat ceiling then stop vy# movement

if ny#<-slope# then vy# = gravity#

endif

else

rem nothing below player, not on ground, add vertical speed to player

oldy# = oldy# + vy#

ground = 0

endif

rem jumptimer will decrease only when player is back on ground

rem creates a pause between two successive jumps

if ground = 1 and jumptimer>0 then dec jumptimer

rem handle horizontal movement as sliding

rem player only collides with group 1 (level) objs and moves freely through others

collide = sc_SphereSlideGroup(1,oldx#,oldy#,oldz#,x#,oldy#,z#,radius#,0)

if collide>0

rem if hit, reposition player, halt movement vector

x# = sc_getCollisionSlideX()

oldy# = sc_getCollisionSlideY()

z# = sc_getCollisionSlideZ()

vx# = 0

vz# = 0

rem possible code for giving the player a jumping help up stairs...

rem might be useful if slope# is set very high but stairs are still required

`dy# = oldy#-sc_getStaticCollisionY()

`if dy#<slope# and dy#>0 and ground=1 then vy# = 0.5

endif

rem position the player

position object 2,x#,oldy#,z#

rem position object 10,x#,oldy#,z# : ` position skysphere unrem if sky moves with player

sc_updateObject 2

endfunction

function positionCameraToObject(obj,thirdPerson)

fpsviewy#=object position y(2)+radius#: ` camera on top of sphere

position camera object position x(2),fpsviewy#,object position z(2)

rotate camera object angle x(2),object angle y(2),object angle z(2)

if thirdPerson=1

pitch camera down 10

move camera -30

endif

set camera range 1,50010 : ` gets rid of blue screen in distance

endfunction

Function makeMinimap(xstart as float, ystart as float, zstart as float)

set camera range 2, 1,50010 : ` gets rid of blue screen in distance

position camera 2,xstart,ystart+radius#,zstart

rotate camera 2,object angle x(2),object angle y(2),object angle z(2)

set camera view 2,screen width() - 150, screen height() - (screen height() - 10), screen width() - 10, screen height() - (screen height() - 150)

CodeBase - FPS code with mini view that uses a dbo level or map

Information

Summary

Full Description

DarkBASIC Professional Source Code

Download

Screen Shot

Author

Comments

Author Name:	Softwizz
CodeBase Entries:	1