TheGameCreators - CodeBase

Return to the CodeBase listing

Category: Games

Version: 1.0

Information

Uploaded: 11th Apr 2018 06:46

Modified: 12th Apr 2018 03:23

Author: fubarpk

Summary

Complete 3D minigame showing a never ending world by wrapping objects in a predefined workspace

Full Description

Demonstrates using multiple objects and scrolling them within a 3d workspace<br /> Displays the use of raycasting<br /> Shows how to create your own particle effects<br /> Demonstrates the sun and fog effects<br /> Creates all media at runtime

AGKV2 BASIC Source Code

` This code was downloaded from The Game Creators

` It is reproduced here with full permission

` http://www.thegamecreators.com

//questions and comments https://forum.thegamecreators.com/thread/222010

#constant KEY_LEFT  =  37 //the left arrow key scancode

#constant KEY_UP =  38    //the up arrow key scancode

#constant KEY_RIGHT = 39  //the right arrow key scancode

#constant KEY_DOWN  =  40 //the down arrow key scancode

#constant KEY_A = 65	  //the scan code for the "a" key

#constant KEY_Z = 90      //the scan code for the "z" key

#constant mapX=40 //maximum blocks on x plane CHANGE THIS TO MAKE ROAD NARROWER IE 20 WHICH WILL SPEED IT UP

#constant mapY=1 //maximum blocks on y plane

#constant mapZ=40 //maximum blocks on z plane

#constant raiseAmmount=8 //the ammount to raise or lower each blocks vertexs

#constant speed#  = 10.0 //the following for a sine curve to repesent hils on the yplane

#constant xMaxResolution=1024

#constant yMaxResolution=768

#constant acceleration#=.01 //used to calclate the carSpeed#

#constant maxCarSpeed#=1.0 //The Maximum speed the carBlock will move

#constant minRand=50 // the minimum the randmoness# can get hence and create more obstacles

global randomness# = 200  //the lower this value the harder it gets its decreased over time automatically

global blockCount

global carBlock=10000 //carblock and carMem have the same referrence

global carMem=10000   //the carBlocks memblock id

global lives=10       //The actual lives of a player

global score=0        //holds the player score whiched is based on progression

global texture1 	  //the detailed texture

global texture2 	  //the texture without detail

time#=timer()		  //holds the startTime for calculations of the sineCurve with the movements and used in calculating an acceleration curve

local carSpeed#=.5          //car speed used for acceleration with timer

local sound1 as integer

local sound2 as integer

//global y# as float = 0.0

dim blocksChanged[mapX*mapY*mapZ] as block

// show all errors

SetErrorMode(2)

// set window properties

SetWindowTitle( "Mini 3d driving game with blocks" )

SetWindowSize( xMaxResolution, yMaxResolution, 0 )

SetWindowAllowResize( 1 ) // allow the user to resize the window

// set display properties

SetVirtualResolution( xMaxResolution, yMaxResolution ) // doesn't have to match the window

SetOrientationAllowed( 1, 1, 1, 1 ) // allow both portrait and landscape on mobile devices

SetSyncRate( 60, 0 ) // 30fps instead of 60 to save battery

SetScissor( 0,0,0,0 ) // use the maximum available screen space, no black borders

UseNewDefaultFonts( 1 ) // since version 2.0.22 we can use nicer default fonts

type vertex

xDirection as integer

yDirection as integer

zDirection as integer

endtype

type block

id as integer

flag as integer

yPos as integer

xPosStart as integer

yPosStart as integer

zPosStart as integer

//the following used for my particle effect

xDirection as float

yDirection as float

zDirection as float

colorWhite as float

endtype

num=1:texture1=createtexture(32,32, makecolor(255,255,255),155):texture2=createtexture(32,32,makecolor(255,255,255),5)

for y = 1 to mapY

for x = 1 to mapX

for z = 1 to mapZ

CreateObjectBox(num,1,1,1)

c=random(100,150)

SetObjectColor(num,c,c,c,255)

SetObjectImage(num,texture1,0)

SetObjectCollisionMode( num, 1 ) //On is needed for raycasting

CreateMemblockFromObjectMesh(num,num,1) //there is exactly the same number of blocks as memblocks and each id is equal

//the shadow is set to off on each block as its only needed for the raised ones

SetObjectCastShadow(num,0)

blocksChanged[num].id=num

//the directions are only used for the particle effect when you crash

blocksChanged[num].xDirection=Random2(-100,100)/50.0

blocksChanged[num].yDirection=Random2(-100,100)/50.0

blocksChanged[num].zDirection=Random2(-100,100)/50.0

blocksChanged[num].yPos=y

blocksChanged[num].xPosStart=x

blocksChanged[num].yPosStart=y

blocksChanged[num].zPosStart=z

blocksChanged[num].colorWhite=0

//SetObjectImage( num, random(1,20), 0)

SetObjectPosition(num,x,y,z)

inc num

next z

next x

next y

blockCount=num-1

CreateObjectBox(carBlock,1,1,2)

CreateMemblockFromObjectMesh(carBlock,carMem,1)

SetObjectCastShadow(carBlock, 1 ) //set shadows on for the carBlock

setObjectPosition(carBlock,mapX/2,mapY+3,10)

SetObjectColor(carBlock,200,0,0,255) //red cars go faster

SetObjectCollisionMode(carBlock,1) //on is set or raycasting wont work

sound1=createSound(1) //creates a base rumble

sound2=createSound(2) //creates white noise

SetSunActive(1)

SetSunColor( 255, 255,255 )

SetFogSunColor( 20, 20, 20 )

//Add some atmosphere

SetFogMode( 1 )

SetFogColor(20,20,20)

SetFogRange(10,100)

SetShadowMappingMode(3 )

SetShadowSmoothing( 0)

SetShadowMapSize( 512, 512 )

SetShadowRange( -1 ) // use the full camera range

//SetShadowBias( 0.0012 ) // offset shadows slightly to avoid shadow artifacts

setCameraPosition(1,mapX/2,10,0)

ResetTimer():time#=timer()

repeat

if GetRawKeyState (KEY_LEFT)

moveBlocks(.5,0,0)

endif

if GetRawKeyState (KEY_RIGHT)

moveBlocks(-.5,0,0)

endif

moveBlocks(0,0,carSpeed#)

//The first raycast is used to set the height of the carBlock

x#=getObjectX(carBlock)

y#=GetObjectY(carBlock)

z#=getObjectZ(carBlock)

// calculate the start of the ray cast

start_x# = x#

start_y# = y#

start_z# = z#

// calculate the end of the ray cast

end_x# = x#+1.0

end_y# = y#-4.0

end_z# = z#+2

hit=ObjectRayCast(0,start_x#,start_y#,start_z#,end_x#,end_y#,end_z#)

if hit>0

rem move car according to hill height

SetObjectPosition(carBlock,GetObjectX(carBlock),GetObjectY(hit)+2,GetObjectZ(carBlock))

SetObjectCastShadow(carBlock, 1 )

endif

//the second raycasting is used for crashes

x#=getObjectX(carBlock)

y#=GetObjectY(carBlock)+2

z#=getObjectZ(carBlock)

// calculate the start of the ray cast

start_x# = x#

start_y# = y#

start_z# = z#

// calculate the end of the ray cast

end_x# = x#+1.0

end_y# = y#-2.0

end_z# = z#+2

hit=ObjectRayCast(0,start_x#,start_y#,start_z#,end_x#,end_y#,end_z#)

if hit>0 //player crashed

dec lives

PlaySound(sound1,100,0)

PlaySound(sound2,50,0)

blocksExplode()

restoreBlocks()

carSpeed#=.5  //Set the speed back to its default as you crashed

time#=timer()

endif

//randomness is used to determine if blocks should be raised and colored or not increases with time

if randomness#>minRand then randomness#=randomness#-.001

if timer()>time#+1.0

carSpeed#=carSpeed#+acceleration# //increase the car speed every 1 second

time#=timer()

endif

if carSpeed#>maxCarSpeed# then carSpeed#=maxCarSpeed#

print ("Mini 3D Driving Game")

print ("use arrow keys")

print ("Esc exits")

print ("Score="+str(score))

print ("Lives="+str(lives))

print("FPS:"+str(screenFPS()))

sync()

until GetRawKeyPressed(27) or lives <1

repeat

Print("Game over")

print ("Score="+str(score))

print("Press Escape to Exit Program")

sync()

until GetRawKeyPressed(27)

end //exitprogram

function modifyBlock(block as integer,  ammount as integer)

rem there are the following 8 vertexs that we need to modify to extend in the ydirection [0,2,4,6,8,9,10,11]

vertex as integer[7] = [0,2,4,6,8,9,10,11]

maxVertex=GetMemblockInt(block,0)-1

for index = 0 to 7

if index<=maxVertex

SetMeshMemblockVertexPosition(block,vertex[index],GetMeshMemblockVertexX(block,vertex[index]),GetMeshMemblockVertexY(block,vertex[index])+ammount,GetMeshMemblockVertexZ(block,vertex[index]))

endif

next index

SetObjectMeshFromMemblock(block,1,block)

endfunction

function moveBlocks(x as float,y as float,z as float)

rem These define the maximum and minimum an object may be placed in this example all objects

rem are 1,1,1 so defing these locations was done as following but could be calculated for

rem other objects of different dimmensions

xNum=mapX-1 //number of objects placed accross the xplane-1

yNum=mapY-1 //number of objects placed accross the yplane-1

zNum=mapZ-1 //number of objects placed accross the zplane-1

rem defing the 3d window workspace

xMin=0:xMax=mapX //the minimum and maximum xlocations for wrapping blocks on x plane

yMin=1:yMax=mapY //the minimum and maximum ylocation for wrapping blocks on the y plane

zMin=0:zMax=mapZ //the minimum and maximum zlocations for wrapping blocks on z plane

time#=timer()

for num=1 to blockCount

if x<0 //move blocks right

if GetObjectWorldX(num)<xMin

SetObjectPosition(num,getObjectX(num)+xNum,getObjectY(num),getObjectZ(num))

else

SetObjectPosition(num,getObjectX(num)+x,getObjectY(num),getObjectZ(num))

endif

if x>0 //move blocks Left

if GetObjectWorldX(num)>xMax

SetObjectPosition(num,getObjectX(num)-xNum,getObjectY(num),getObjectZ(num))

else

SetObjectPosition(num,getObjectX(num)+x,getObjectY(num),getObjectZ(num))

endif

if z>0 //move blocks toward screen

if GetObjectWorldZ(num)<zMin

SetObjectPosition(num,getObjectX(num),blocksChanged[num].yPos,getObjectZ(num)+zNum)

x# = sin(time#*speed#)*200

y# = sin(time#*speed#*2)*100 // ranges from -100 to 100

y#=y#/50.0 //if this division is set to low the raycasting needs changing 50 and 75 both work well

moveBlockYDirection(num,y#)

if blocksChanged[num].colorWhite=0 and getObjectWorldz(1)<=zMin //for white checkpoint line

SetObjectColor(num,255,255,255,255)

SetObjectImage(num,texture2,0)

blocksChanged[num].colorWhite=1

else

c=random(100,150)

SetObjectColor(num,c,c,c,255)

SetObjectImage(num,texture1,0)

blocksChanged[num].colorWhite=0

endif

if blocksChanged[num].flag=0 //random color then raise block 8

if Random(1,randomness#)<2

modifyBlock(num,raiseAmmount)

blocksChanged[num].flag=1

SetObjectCastShadow(num,1)

SetObjectColor(num,random(1,255),random(1,255),random(1,255),255)

SetObjectImage(num,texture2,0)

endif

else

modifyBlock(num,-raiseAmmount) //lower block

blocksChanged[num].flag=0

SetObjectCastShadow(num,0)

c=random(100,150):SetObjectColor(num,c,c,c,255)

SetObjectImage(num,texture1,0)

endif

else

SetObjectPosition(num,getObjectX(num),getObjectY(num),getObjectZ(num)-z)

rem block 40 is off the screen so increment score

if num=40 then inc score

endif

next num

endfunction

function moveBlockYDirection(num,y as float)

//move blocks on the yplane as set by the sine curve

blocksChanged[num].yPos=y

SetObjectPosition(num,getObjectX(num),blocksChanged[num].yPos,getObjectZ(num))

endfunction

function blocksExplode()

//vertexFront as integer[4] = [0,1,2,3] rem front face

//vertexRight as integer[4] = [4,5,6,7] rem right face

//vertexTop as integer[4] = [8,9,10,11] rem top face

//vertexLeft as integer[4] = [12,13,14,15] rem left face

//vertexBottom as integer[4] = [20,21,22,23] rem bottom face

//vertexBack as integer[4] = [16,17,18,19] rem back face

//if you just want to seperate each face from the car set the same directions for each face as described above

maxVertex=GetMemblockInt(carBlock,0)-1

Dim CarVertex[maxVertex] as vertex

For index=0 to maxVertex

//set each vertex a random direction

CarVertex[index].xDirection=random2(-100,100)/50.0

CarVertex[index].yDirection=Random2(-100,100)/50.0

CarVertex[index].zDirection=Random2(-100,0)/50.0

next index

startTime#=Timer()

repeat

for num=1 to blockCount

//move the ground blocks in their set random directions

SetObjectPosition(num,getObjectX(num)+blocksChanged[num].xDirection,getObjectY(num)+blocksChanged[num].yDirection,getObjectZ(num)+blocksChanged[num].zDirection)

next num

for index = 0 to maxVertex

//Tear the cars vertexs apart as set by there random direction

SetMeshMemblockVertexPosition(carMem,index,GetMeshMemblockVertexX(carMem,index)+CarVertex[index].xDirection,GetMeshMemblockVertexY(carMem,index)+CarVertex[index].yDirection,GetMeshMemblockVertexZ(carMem,index)+CarVertex[index].zDirection)

next index

SetObjectMeshFromMemblock(carBlock,1,carMem)

print ("Mini 3D Driving Game")

print ("use arrow keys")

print ("Esc exits")

print ("Score="+str(score))

print ("Lives="+str(lives))

print("FPS:"+str(screenFPS()))

sync()

until timer()>StartTime#+3

endfunction

function restoreBlocks()

//restore all the block properties after a collision

for num=1 to blockCount

//restore blocks to the starting positions

SetObjectPosition(blocksChanged[num].id,blocksChanged[num].xPosStart,blocksChanged[num].yPosStart,blocksChanged[num].zPosStart)

SetObjectCastShadow(num,0) 	//set all blocks to no shadows

rem the blocks that have been raised return them back to how they started

if blocksChanged[num].flag=1

modifyBlock(num,-raiseAmmount)

blocksChanged[num].flag=0

blocksChanged[num].colorWhite=0

c=random(100,150)

SetObjectColor(num,c,c,c,255)

SetObjectImage(num,texture1,0)

endif

next num

rem because the cars vertexs are destroyed delete the car and memblock and recreate them

DeleteObject(carBlock)

DeleteMemblock(carMem)

CreateObjectBox(carBlock,1,1,2)

CreateMemblockFromObjectMesh(carBlock,carMem,1)

SetObjectCastShadow(carBlock, 1 )

setObjectPosition(carBlock,mapX/2,mapY+3,10)

SetObjectColor(carBlock,200,0,0,255) //red cars go faster

SetObjectCollisionMode(carBlock,1)

endfunction

function createSound(num as integer)

//create sound wave in memory

local sound as integer

local frames as integer

local data as integer

local size as integer

local mem as integer

local sec as float

sec = .4

data = sec * (44100 * (2*2)) // 176400 bytes per second

frames = data / 4

size = 2+2+4+4 + data

mem = CreateMemblock(size)

SetMemblockByte(mem,0, 2) //The first 2 bytes of the memlbock store the number of channels (1 or 2 supported)

SetMemblockByte(mem,1, 0)

SetMemblockByte(mem,2,16) //the next 2 bytes store the bits per sample (8 (1 byte) or 16 (2 byte) supported)

SetMemblockByte(mem,3, 0)

SetMemblockint(mem,4,44100) // the next 4 bytes store the samples per second, for example 44100

SetMemblockint(mem,8,frames) // The next 4 bytes are the number of frames in the sound data, the size of the sound data in bytes can be calculated from this with the formula numFrames*(bitsPerSample/8)*channels.

local i as integer

local value as integer

local Hz as float // the hertz of the sound

local w as float

value=0

w=0

local randomize as integer[8]=[80,53,-25,73,44,0,24,80] //deep base rumble

maxW=360:if num=2 then maxW=32768 //360 is normal

for i=0 to data -1 step 4

Hz=randomize[random2(1,8)] //deep base rumble

w=w+(maxW / 44100.0) * Hz

if w > maxW then w = w -maxW

value = sin(w)*(32767.0) //Max ?32768 through 32767

SetMemblockShort(mem,12+i+0 ,value) // short 2 bytes ?32768 through 32767

SetMemblockShort(mem,12+i+2 ,value) // short 2 bytes ?32768 through 32767

next i

sound = CreateSoundFromMemblock(mem)

DeleteMemblock(mem)

endFunction sound

// 102, 51, 0

// Function to create a texture

// Inputs - Sizex - size of the texture to create - width

//          Sizey - size of the texture to create - height

//          Color - is the main color of the image

//          Denisity - is a the depth of the texture - the lower the value, the more detail. higher value = no detail

// Returns the image for the resulting texture

// EG. CreateTexture ( 100, 100,  makecolor(0,0,255), 100)

//          This could create a DEEP water effect texture?

function createtexture(sizex# as float, sizey# as float, color, density as integer)

swap()

drawbox(0,0,sizex#, sizey#, color, color,color,color, 1)

render()

img = getimage(0,0,sizex#, sizey#)

memblockid = CreateMemblockFromImage (img)

imgwidth = GetMemblockInt(memblockid, 0)

imgheight = GetMemblockInt(memblockid, 4)

size=GetMemblockSize(memblockid)

for offset=12 to size-4 step 4

r=GetMemblockByte(memblockid, offset)

g=GetMemblockByte(memblockid, offset+1)

b=GetMemblockByte(memblockid, offset+2)

a=GetMemblockByte(memblockid, offset+3)

strength=random(1,density)

SetMemblockByte (memblockid, offset, r-strength)

SetMemblockByte (memblockid, offset+1, g-strength)

SetMemblockByte (memblockid, offset+2, b-strength )

SetMemblockByte (memblockid, offset+3, a-strength)

deleteimage (img)

img = CreateImageFromMemblock(memblockid)

DeleteMemblock(memblockid)

endfunction img

Download

Please login to download

Comments

No comments yet.

CodeBase - 3D Minigame

Information

Summary

Full Description

AGKV2 BASIC Source Code

Download

Screen Shot

Author

Comments

Author Name:	fubarpk
CodeBase Entries:	12