TheGameCreators - CodeBase - Rolling ball demo

Return to the CodeBase listing

Category: Basic 3D

Version: 1.052

Information

Uploaded: 18th Apr 2004 14:15

Modified: 1st Jan 1970 01:00

Author: Fredsky

Summary

ROLLING BALL AND 2D RIGID BODY PHYSICS DEMO

Full Description

You can control a ball with the mouse, the mouse doesn't control the ball directly it changes the accelleration.<br /> I hope that you find that the ball control feels natural.<br /> The ball texture moves in the correct direction, for this I have used the EZrotate dll by Ron Erickson.<br /> You can bounce around a cube with the ball.<br /> No external media files are needed, the textures are generated in software

DarkBASIC Professional Source Code

` This code was downloaded from The Game Creators

` It is reproduced here with full permission

` http://www.thegamecreators.com

` ROLLING BALL AND 2D RIGID BODY PHYSICS DEMO

`-------------------------------------------------------------

` Darkbasic Pro V1.052

` Author : Hedwig Janssens

` Date : 11/04/2004

`This piece of code uses EZrotate by Ron Erickson  (Thanks Ron)

`The "EZrotate.dll" must be installed into your "Dark Basic Professional/Compiler/plugins-user" folder

`Download EZrotate at http://www.ericksonline.com

SET DISPLAY MODE 800,600,16

sync rate 50

sync on

hide mouse

set ambient light 50

make light 1

position light 1,0,-200,0

POINT LIGHT 1,0,0,0

MakeCheckerBoard(rgb(255,55,55),rgb(55,255,155),32)

GET IMAGE 2,0,0,255,255

make object sphere 1,50,30,30

texture object 1,2

SET OBJECT COLLISION TO SPHERES 1

`SET OBJECT RADIUS 1,25

SET OBJECT COLLISION ON 1

MakeCheckerBoard(rgb(155,155,255),rgb(200,220,255),128)

GET IMAGE 3,0,0,255,255

MAKE OBJECT CUBE 2, 50

texture object 2,3

SET OBJECT COLLISION TO BOXES 2

SET OBJECT COLLISION ON 2

MakeCheckerBoard(rgb(153,138,0),rgb(201,181,0),16)

GET IMAGE 4,0,0,255,255

make object plain 10, 440, 440

texture object 10, 4

ROTATE object 10,90,0,0

position object 10, 0, 0, 0

set camera fov 50

Maxsp#=9   `Maximum speed

Frict#=0.02 `Friction constant

MouseSense#=0.02 `Mouse sensitivity

cxp#=100:cyp#=8  `Initial cube position

cama#=30: camx#=0 : camy#=270 :camz#=-420 `Camera position

sm#=1 `Sphere mass

cm#=1 `Cube mass

`VARS Sphere position sxp#,syp#  speed sxv#,syv#  mass sm#

`VARS Cube   position cxp#,cyp#  speed cxv#,cyv#  mass cm#

SET TEXT SIZE 22

text 3,0,"ROLLING BALL AND 2D RIGID BODY PHYSICS DEMO"

SET TEXT SIZE 16

text 3,20,"Move camera: Left button + drag up/down   Right button + drag  Left/Right Forward/Backward"

text 3,32,"Change camera angle with mouse wheel"

text 3,44,"Press space to stop all movement"

text 3,56,"Mouse with no buttons pressed controls ball"

if sm#=1 and cm#=1 then text 3,70,"Press 1-3: Equal mass"

if sm#=3 and cm#=1 then text 3,70,"Press 1-3: Heavy sphere"

if sm#=1 and cm#=3 then text 3,70,"Press 1-3: Heavy cube"

moux=MOUSEMOVEX(): mouy=MOUSEMOVEY(): mouz=MOUSEMOVEZ()

if MOUSECLICK()=2 `Right mouse controls camera Left/Right  Forward/Backward

camx#=camx# - moux * 0.5

camz#=camz# + mouy * 0.5

endif

if MOUSECLICK()=1 `Left mouse controls camera Up/DOWN

camy#=camy# + mouy * 0.5

endif

cama#=cama# + mouz * 0.03 `Mouse wheel controls camera angle

position camera camx#,camy#,camz#

rotate camera cama#,0,0

`Rotate ball with help of the EZrotate.dll

EZro_Set OBJECT ANGLE X(1),OBJECT ANGLE Y(1),OBJECT ANGLE Z(1)

EZro_GX syv#*2

EZro_GZ -sxv#*2

ROTATE OBJECT 1,EZro_GetX(),EZro_GetY(),EZro_GetZ()

position object 1,sxp#,25,syp#

position object 2,cxp#,25,cyp#

if OBJECT COLLISION(1,2)=1

sxp#=sxpo#:syp#=sypo# `Restore to pre collision position

cxp#=cxpo#:cyp#=cypo# `Restore to pre collision position

tcxv#=cxv# * (cm# - sm#) / (cm# + sm#) + sxv# * (2 * sm#) / (cm# + sm#)

tcyv#=cyv# * (cm# - sm#) / (cm# + sm#) + syv# * (2 * sm#) / (cm# + sm#)

sxv#=sxv# * (sm# - cm#) / (sm# + cm#) + cxv# * (2 * cm#) / (sm# + cm#)

syv#=syv# * (sm# - cm#) / (sm# + cm#) + cyv# * (2 * cm#) / (sm# + cm#)

cxv#=tcxv#

cyv#=tcyv#

endif

cxpo#=cxp#:cypo#=cyp# `Save last position

cxp#=cxp# + cxv# : cxv#=friction(cxv#,Frict#)

cyp#=cyp# + cyv# : cyv#=friction(cyv#,Frict#)

cxv#=limit(cxv#,Maxsp#)

cyv#=limit(cyv#,Maxsp#)

if cxp#>195 then cxv#=-abs(cxv#)

if cyp#>195 then cyv#=-abs(cyv#)

if cxp#<-195 then cxv#=abs(cxv#)

if cyp#<-195 then cyv#=abs(cyv#)

sxpo#=sxp#:sypo#=syp# `Save last position

sxp#=sxp# + sxv# : sxv#=friction(sxv#,Frict#)

syp#=syp# + syv# : syv#=friction(syv#,Frict#)

if sxp#>195 then sxv#=-abs(sxv#)

if syp#>195 then syv#=-abs(syv#)

if sxp#<-195 then sxv#=abs(sxv#)

if syp#<-195 then syv#=abs(syv#)

if MOUSECLICK()=0

sxv#=sxv# + moux * MouseSense#

sxv#=limit(sxv#,Maxsp#)

syv#=syv# - mouy * MouseSense#

syv#=limit(syv#,Maxsp#)

endif

if keystate(2) then sm#=1 : cm#=1

if keystate(3) then sm#=3 : cm#=1

if keystate(4) then sm#=1 : cm#=3

if keystate(57) then cxv#=0 : cyv#=0 :sxv#=0 : syv#=0

sync

loop

function friction(val#,amount#)

if val#<0

val#=val# + amount#

else

val#=val# - amount#

endif

if abs(val#)<=amount# then val#=0

endfunction val#

function limit(val#,amount#)

if val#>Amount# then val#=Amount#

if val#<-Amount# then val#=-Amount#

Endfunction val#

`Draw a checkerboard pattern

` IN: color 1,color 2,size of squares

`OUT: void

function MakeCheckerBoard(col1,col2,size)

c=0

for x=0 to 256/size-1 : for y=0 to 256/size-1

c=1-c

if c=0

ink col1,0

else

ink col2,0

endif

BOX x*size,y*size,x*size+size,y*size+size

next y :c=1-c :next x

endfunction

Download

Please login to download

Comments

No comments yet.

Author Name:	Fredsky
CodeBase Entries:	1

CodeBase - Rolling ball demo

Information

Summary

Full Description

DarkBASIC Professional Source Code

Download

Screen Shot

Author

Comments