TheGameCreators - CodeBase - Animated Sprites placed with mouse click

Return to the CodeBase listing

Category: Sprite

Version: 1.0

Information

Uploaded: 23rd Feb 2008 23:25

Modified: 23rd Feb 2008 23:28

Author: Visigoth

Summary

A small program that demonstrates placing 2D sprites where the mouse is clicked.

Full Description

I've been fooling around abit with sprites lately, and came up with this code to place animated sprites whereever the mouse is clicked. It uses a sprite type and a mouse type to keep track of the mouse state as well as sprite info. It will place a sprite, play it, then delete it after it is done playing it. Requires the media file for 2 images in the code.

DarkBASIC Professional Source Code

` This code was downloaded from The Game Creators

` It is reproduced here with full permission

` http://www.thegamecreators.com

REM Project: sprites

REM Created: 2/23/2008 1:34:51 PM

REM

REM ***** Main Source File *****

REM

rem Created by Mike Shihrer, aka Visigoth

rem Just a simple method to display animated sprites with the click of a mouse.

rem Sprites are positioned and played at the position mouse is at when the LMB is clicked

autocam off

sync on

sync rate 0

hide mouse

load image "mousepointer2.bmp",1  rem custom mouse pointer

sprite 1,mousex(),mousey(),1

rem this is just to see what the sprites look like over a 3d object

make object sphere 1,25

position object 1,0,0,100

rem create a type to hold mouse info

type mouse_state

count as integer

state as integer

endtype

rem declare the type as global

global m_state as mouse_state

m_state.count = 0

m_state.state = 0

rem create a type to hold sprite info

type sprite_type

id as integer               rem the actual sprite number is stored here

f_name as string

state as integer            rem stores the state of the sprite, playing or not playing

xpos# as float              rem stores the x position of the mouse when clicked

ypos# as float              rem stores the y position of the mouse when clicked

frame as integer            rem stores the current frame of sprite animation being played

across_frames as integer    rem how many frames across the sprite image is

down_frames as integer      rem how many frames down the sprite image is

total_frames as integer     rem total frames in the animated sprite image

delay as integer            rem speed of sprite playback. Higher is slower

total_sprites as integer    rem how many sprites you need to reserve

endtype

rem create a global array of sprite_types

rem depending on how fast you click your mouse

rem or how many frames of animation, this may need to be larger

t_sprites = 20

global dim my_sprite(t_sprites) as sprite_type

rem initialize sprite_type

ii = 1

for i = 1 to t_sprites

my_sprite(i).id = i + ii

my_sprite(i).f_name = "explosion64.png"

my_sprite(i).state = 0

my_sprite(i).xpos# = 0

my_sprite(i).ypos# = 0

my_sprite(i).frame = 1

my_sprite(i).across_frames = 16

my_sprite(i).down_frames = 1

my_sprite(i).total_frames = (my_sprite(i).across_frames * my_sprite(i).down_frames)

my_sprite(i).delay = 60

my_sprite(i).total_sprites = t_sprites

inc ii,1

next i

///////////////////////////MAIN_LOOP///////////////////////////////

///////////////////////////////////////////////////////////////////

sprite 1,mousex(),mousey(),1           rem position mouse sprite

mouse_click()                          rem poll the mouse

for i = 1 to t_sprites                 rem loop through the sprite array, and play the ones that are state set to 1

play_sprite(i)

next i

sync

loop

///////////////////////////////////////////////////////////////////

function mouse_click()

rem left mouse button

if mouseclick() = 1  and m_state.state = 0               rem so it doesn't just "paint" the sprites

m_state.state = 1

inc m_state.count,1                                   rem keep track of how many times we clicked

if m_state.count = (my_sprite(1).total_sprites + 1)   rem we reserved my_sprite(1).total_sprites sprites in the array, so don't go more than that

m_state.count = 1

endif

my_sprite(m_state.count).id = m_state.count + 1       rem because our mouse pointer is image 1, we have to add one to the sprite ID

my_sprite(m_state.count).state = 1                    rem our sprite is set to play

my_sprite(m_state.count).xpos# = mousex()             rem store the mouse x position

my_sprite(m_state.count).ypos# = mousey()             rem store the mouse y position

create animated sprite my_sprite(m_state.count).id,my_sprite(m_state.count).f_name,my_sprite(m_state.count).across_frames,my_sprite(m_state.count).down_frames,my_sprite(m_state.count).id

endif

rem right mouse button

rem can be used for ther effects

if mouseclick() = 2 and m_state.state = 0

m_state.state = 2

endif

rem mouse button up

if mouseclick() = 0

m_state.state = 0

endif

endfunction

function play_sprite(id as integer)

rem pretty straight forward here

rem just check the state of each sprite in the array

rem and if it is one, paste the sprite

rem and then play it

rem keep track of how many frames, and delete the

rem sprite after it is at the last frame

if my_sprite(id).state = 1

rem centers the sprite on the mouse pointer

paste sprite my_sprite(id).id,my_sprite(id).xpos# - (sprite width(my_sprite(id).id) * .5),my_sprite(id).ypos# - (sprite height(my_sprite(id).id) * .5)

play sprite my_sprite(id).id,1,my_sprite(id).total_frames,my_sprite(id).delay

inc my_sprite(id).frame,1

if sprite frame(my_sprite(id).id) = my_sprite(id).total_frames

my_sprite(id).state = 0

my_sprite(id).frame = 1

delete sprite my_sprite(id).id

endif

endfunction

Download

Please login to download

Comments

No comments yet.

Author Name:	Visigoth
CodeBase Entries:	18

CodeBase - Animated Sprites placed with mouse click

Information

Summary

Full Description

DarkBASIC Professional Source Code

Download

Screen Shot

Author

Comments